name
ControllIO
openExample

    import processing.opengl.*;

    import procontroll.*;
    import net.java.games.input.*;

    ControllIO controllIO;
    ControllDevice joypad;
    ControllStick stick1;
    ControllStick stick2;

    float transX;
    float transY;

    void setup(){
      size(600,600,OPENGL);

      transX = width/2;
      transY = height/2;

      controllIO = ControllIO.getInstance(this);

      joypad = controllIO.getDevice("Logitech RumblePad 2 USB");
      joypad.plug(this, "handleButton1Press", ControllIO.ON_PRESS, 1);
      joypad.plug(this, "handleButton1Release", ControllIO.ON_RELEASE, 1);
      joypad.plug(this, "handleMovement", ControllIO.WHILE_PRESS, 0);

      stick1 = joypad.getStick(0);
      stick1.setMultiplier(PI);

      stick2 = joypad.getStick(1);
      stick2.setTolerance(0.06f);
      stick2.setMultiplier(0.05f);
    }

    void handleButton1Press(){
      fill(255,0,0);
      joypad.rumble(1);
    }

    void handleButton1Release(){
      fill(255);
    }

    void handleMovement(final float i_x,final float i_y){
      transX += i_x;
      transY += i_y;
    }

    void draw(){
      background(0);
      lights();
      translate(transX,transY,0);
      rotateX(stick2.getTotalY());
      rotateY(stick2.getTotalX());
      box(200);
    }

description

ControllIO is the base class for using controllers in Processing. It provides methods to retrieve information about the connected devices and to get the input data from them.
To get a ControllIO object you to use the getInstance() Method. As a startup you should use the printDevices() to see if all Controllers are connected and correctly found.

To react on button events you can plug methods, that are called when a button is pressed, released or while a button is pressed.

constructors

    none available

methods
getDevice ( )
Use this method to get a device.
getInstance ( )
Use this method to get a ControllIO instance.
getNumberOfDevices ( )
Returns the number of available Devices
plug ( )
Plugs a method to handle button events.
printDevices ( )
Lists the available Devices in the console window.
usage
application
related
ControllDevice